mirror of
https://github.com/bpg/terraform-provider-proxmox.git
synced 2025-07-05 05:24:01 +00:00
130 lines
3.2 KiB
Markdown
130 lines
3.2 KiB
Markdown
# HOW-TO Configure a VM with Cloud-Init
|
|
|
|
> [!NOTE]
|
|
> Examples below use the following defaults:
|
|
>
|
|
> - a single Proxmox node named `pve`
|
|
> - local storages named `local` and `local-lvm`
|
|
|
|
## Native Proxmox Cloud-Init support
|
|
|
|
Proxmox supports Cloud-Init natively, so you can use the `initialization` block to configure your VM:
|
|
|
|
```terraform
|
|
resource "proxmox_virtual_environment_vm" "ubuntu_vm" {
|
|
name = "test-ubuntu"
|
|
node_name = "pve"
|
|
|
|
initialization {
|
|
|
|
ip_config {
|
|
ipv4 {
|
|
address = "192.168.3.233/24"
|
|
gateway = "192.168.3.1"
|
|
}
|
|
}
|
|
|
|
user_account {
|
|
username = "ubuntu"
|
|
keys = [trimspace(data.local_file.ssh_public_key.content)]
|
|
}
|
|
}
|
|
|
|
disk {
|
|
datastore_id = "local-lvm"
|
|
file_id = proxmox_virtual_environment_download_file.ubuntu_cloud_image.id
|
|
interface = "virtio0"
|
|
iothread = true
|
|
discard = "on"
|
|
size = 20
|
|
}
|
|
|
|
network_device {
|
|
bridge = "vmbr0"
|
|
}
|
|
}
|
|
```
|
|
|
|
Note that many cloud images do not have `qemu-guest-agent` installed by default, so you won't be able to retrieve the dynamic IP address of the VM from Proxmox, as this is agent's responsibility. You can use the `ip_config` block to configure a static IP address instead.
|
|
|
|
## Custom Cloud-Init configuration
|
|
|
|
Because of several limitations of the native Proxmox cloud-init support, you may want to use a custom Cloud-Init configuration instead. This would allow you to adjust the VM configuration to your needs, and also install the `qemu-guest-agent` and additional packages.
|
|
|
|
In order to use a custom cloud-init configuration, you need to create a `cloud-config` snippet file and pass it to the VM as a `user_data_file_id` parameter. You can use the `proxmox_virtual_environment_file` resource to create the file. Make sure the "Snippets" content type is enabled on the target datastore in Proxmox before applying the configuration below.
|
|
|
|
```terraform
|
|
resource "proxmox_virtual_environment_file" "cloud_config" {
|
|
content_type = "snippets"
|
|
datastore_id = "local"
|
|
node_name = "pve"
|
|
|
|
source_raw {
|
|
data = <<EOF
|
|
#cloud-config
|
|
users:
|
|
- default
|
|
- name: ubuntu
|
|
groups:
|
|
- sudo
|
|
shell: /bin/bash
|
|
ssh_authorized_keys:
|
|
- ${trimspace(data.local_file.ssh_public_key.content)}
|
|
sudo: ALL=(ALL) NOPASSWD:ALL
|
|
runcmd:
|
|
- apt update
|
|
- apt install -y qemu-guest-agent net-tools
|
|
- timedatectl set-timezone America/Toronto
|
|
- systemctl enable qemu-guest-agent
|
|
- systemctl start qemu-guest-agent
|
|
- echo "done" > /tmp/cloud-config.done
|
|
EOF
|
|
|
|
file_name = "cloud-config.yaml"
|
|
}
|
|
}
|
|
```
|
|
|
|
```terraform
|
|
resource "proxmox_virtual_environment_vm" "ubuntu_vm" {
|
|
name = "test-ubuntu"
|
|
node_name = "pve"
|
|
|
|
agent {
|
|
enabled = true
|
|
}
|
|
|
|
cpu {
|
|
cores = 2
|
|
}
|
|
|
|
memory {
|
|
dedicated = 2048
|
|
}
|
|
|
|
disk {
|
|
datastore_id = "local-lvm"
|
|
file_id = proxmox_virtual_environment_download_file.ubuntu_cloud_image.id
|
|
interface = "virtio0"
|
|
iothread = true
|
|
discard = "on"
|
|
size = 20
|
|
}
|
|
|
|
initialization {
|
|
ip_config {
|
|
ipv4 {
|
|
address = "dhcp"
|
|
}
|
|
}
|
|
|
|
user_data_file_id = proxmox_virtual_environment_file.cloud_config.id
|
|
}
|
|
|
|
network_device {
|
|
bridge = "vmbr0"
|
|
}
|
|
|
|
}
|
|
```
|